-- Begin Code --
 set content_ to ""
 set desc_ to ""
 set url_ to ""

 tell application "NetNewsWire"
  set subs_count to count subscriptions
  repeat with i from 1 to subs_count
   set hl_count to count headlines of subscription i
   repeat with x from 1 to hl_count
    if isFlagged of headline x of subscription i is true then
     tell headline x of subscription i
      try
       set desc_ to "Description: " & description
      on error
       set desc_ to "Description: Not Available"
      end try
      
      try
       set url_ to "URL: " & URL
      on error
       set url_ to "URL: Not Available"
      end try
      
      set content_ to content_ & ¬
       ("----------------------------" & ¬
        return & url_ & return & desc_ & ¬
        return & return)
      
      set desc_ to ""
      set url_ to ""
     end tell
    end if
   end repeat
  end repeat
 end tell

 write_to_file(content_, (path to desktop as text) & "NNW Flagged Items.txt", false)

 to write_to_file(this_data, target_file, append_data)
  try
   set the target_file to the target_file as text
   set the open_target_file to ¬
    open for access file target_file with write permission
   if append_data is false then ¬
    set eof of the open_target_file to 0
   write this_data to the open_target_file starting at eof
   close access the open_target_file
   return true
  on error
   try
    close access file target_file
   end try
   return false
  end try
 end write_to_file
-- End Code --